;:sys36864
	;.opt oo
	*= $c000
savev	=$332
openv	=$31a
strout	=$ab1e
oldsave	=$f5ed
oldopen	=$f34a
ga	=$ba
fn	=$bb
len	=$b7
stack	=$100
ay10	=$bf0c
sa	=$b9
listen	=$ffb1
seclist	=$ff93
unlist	=$ffae
iecout	=$ffa8
print	=$ffd2
namout	=$f5c1
direct	=$9d
	lda #<neusave
	ldy #>neusave
	sta savev
	sty savev+1
	lda #<neuopen
	ldy #>neuopen
	sta openv
	sty openv+1
	lda #<public
	ldy #>public
	jmp strout
public	.byt 13
	.byte "don't replace! v1"
	.byt 13,13
	.byte "by nikolaus heusler"
	.byt 13
	.byte "   8ooo muenchen 71"
	.byt 13,13
	.byte "=installed="
	.byt 13,0
comm	.byte " gnihctarcs"
	.byt 13
neusave	jsr pruef
	jmp oldsave
neuopen	jsr pruef
	jmp oldopen
pruef	lda ga
	cmp #8
	bcs floppy
okay	rts
floppy	ldy #0
	lda (fn),y
	cmp #"@"
	bne okay
testdp	iny
	cpy len
	bcs okay
	lda (fn),y
	cmp #":"
	bne testdp
	ldx #0
trans	iny
	cpy len
	beq endnam
	lda (fn),y
	sta stack,x
	inx
	bne trans
endnam	stx len
	jsr ay10
	sta fn
	sty fn+1
	lda ga
	jsr listen
	lda sa
	pha
	lda #$6f
	sta sa
	jsr seclist
	lda #"s"
	jsr iecout
	lda #"0"
	jsr iecout
	lda #":"
	jsr iecout
	ldy #0
sendnam	lda (fn),y
	jsr iecout
	iny
	cpy len
	bcc sendnam
	jsr unlist
	bit direct
	bpl program
	ldx #$b
commout	lda comm,x
	jsr print
	dex
	bpl commout
	jsr namout
program	pla
	sta sa
	rts